Unity Shader系列文章：Unity Shader目录-初级篇

Unity Shader系列文章：Unity Shader目录-中级篇

原理：

想要对包含了顶点动画的物体添加阴影，如果仍然向之前那样使用内置的VertexLit等包含阴影的Pass来渲染，就得不到正确的阴影效果(无法向其他物体正确的投射阴影)。
因为这些内置的ShadowCaster Pass中，并没有进行相关的顶点动画，因此Unity会仍然按照原来的顶点位置来计算阴影，所以我们就需要提供一一个自定义的ShadowCaster Pass，在这个Pass中，我们将进行同样的顶点变换过程。

效果：

Shader代码：

// 顶点动画中的阴影
Shader "Custom/VertexAnimationWithShadow"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" { }
        _Color ("Color Tint", Color) = (1, 1, 1, 1)
        _Magnitude ("Magnitude", Float) = 1 // 波动幅度
        _Frequency ("Frequency", Float) = 1 // 频率
        _InvWaveLength ("InvWaveLength", Float) = 10 // 波长
        _Speed ("Speed", Float) = 0.5
    }

    SubShader
    {
        // "DisableBatching" = "True" 取消对该Shader的批处理操作
        // 因为此Shader包含了模型空间的顶点动画，而批处理会合并所有相关的模型，导致这些模型各自的模型空间丢失
        Tags { "DisableBatching" = "True" }

        Pass
        {
            Tags { "LightMode" = "ForwardBase" }

            Cull Off

            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"

            sampler2D _MainTex;
            // _MainTex纹理的缩放和偏移系数
            float4 _MainTex_ST;
            fixed4 _Color;
            float _Magnitude;
            float _Frequency;
            float _InvWaveLength;
            float _Speed;

            // 应用传递给顶点着色器的数据
            struct a2v
            {
                float4 vertex: POSITION; // 语义：模型顶点坐标
                float4 texcoord: TEXCOORD0; // 语义：模型第一组纹理坐标
            };

            // 顶点着色器传递给片元着色器的数据
            struct v2f
            {
                float4 pos: SV_POSITION;
                float2 uv: TEXCOORD0;
            };

            // 顶点着色器函数
            v2f vert(a2v v)
            {
                v2f o;

                // 计算顶点位移量，只对顶点的x方向进行位移
                float4 offset;
                offset.yzw = float3(0.0, 0.0, 0.0);
                // 使用_Frequency * _Time.y 控制正弦函数的频率
                // 再加上(v.vertex.x + v.vertex.y + v.vertex.z) * _InvWaveLength 让不同的位置具有不同的位移
                // 最后乘以_Magnitude 控制波动幅度
                offset.x = sin(_Frequency * _Time.y + (v.vertex.x + v.vertex.y + v.vertex.z) * _InvWaveLength) * _Magnitude;
                // 将顶点坐标从模型空间变换到裁剪空间
                o.pos = UnityObjectToClipPos(v.vertex + offset);

                // 纹理动画
                o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
                o.uv += float2(0.0, _Time.y * _Speed);

                return o;
            }

            // 片元着色器函数
            fixed4 frag(v2f i): SV_Target
            {
                fixed4 color = tex2D(_MainTex, i.uv);
                color.rgb *= _Color.rgb;

                return color;
            }

            ENDCG

        }

        // 自定义ShadowCaster
        pass
        {
            Tags { "LightMode" = "ShadowCaster" }

            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            #pragma multi_compile_shadowcaster
            
            #include "UnityCG.cginc"

            float _Magnitude;
            float _Frequency;
            float _InvWaveLength;
            float _Speed;

            struct v2f
            {
                V2F_SHADOW_CASTER;
            };

            v2f vert(appdata_base v)
            {
                v2f o;

                float4 offset;
                offset.yzw = float3(0.0, 0.0, 0.0);
                offset.x = sin(_Frequency * _Time.y + (v.vertex.x + v.vertex.y + v.vertex.z) * _InvWaveLength) * _Magnitude;
                v.vertex = v.vertex + offset;

                TRANSFER_SHADOW_CASTER_NORMALOFFSET(o)

                return o;
            }

            fixed4 frag(v2f i): SV_TARGET
            {
                SHADOW_CASTER_FRAGMENT(i)
            }

            ENDCG

        }
    }
    FallBack "VertexLit"
}