PRCOMP/ON
DECL/GLOBAL,CHAR,20,SECU_DIST_CHAR,GageBlock_Len_CHAR,Probe_CHAR
DECL/GLOBAL,DOUBLE,SECU,Gage_Len,Probe_D,STEP_NUM
TEMPSTRING = PROMPT/TEXT,'CNC移动时测头抬高的距离',EDIT,SECU,$
TEXT,'次数',EDIT,STEP_NUM,$
TEXT,'探头直径',EDIT,Probe_D,$
TEXT,'请输入步长',EDIT,Gage_len
M(GAGECRDSETUP) = MACRO/'CRDLABEL', ADVX, ADVZ, GHEIGHT, GWIDTH, GLENGTH, GCLEAR, PRBR
D(@CRDLABEL) = TRANS/ZORIG, ADVZ, XORIG, ADVX
GOTO/10, SECU, 5
F(ZPLANE) = FEAT/PLANE,CART, 0.0, 0.0, 0.0, 0, 0, 1
F(XLINE) = FEAT/LINE,BND,CART, 0, 0, 0, 1, 0, 0, 0, 1, 0
F(XORIG)=FEAT/POINT,CART,6 ,0, 0, -1, 0, 0
MEAS/PLANE,F(ZPLANE), 3
PTMEAS/CART, GCLEAR, -(GHEIGHT/6), 0, 0, 0, 1
PTMEAS/CART, GCLEAR, -(GHEIGHT*2/6), 0, 0, 0, 1
GOTO/3, SECU, 5
GOTO/GLENGTH-3, SECU, 5
PTMEAS/CART, GLENGTH-ENDCLEAR, -(GHEIGHT/4), 0, 0, 0, 1
ENDMES
GOTO/GLENGTH-3, SECU, 5
GOTO/10, SECU, 5
MEAS/LINE,F(XLINE), 2
PTMEAS/CART, GCLEAR, 0, -(GWIDTH/2), 0, 1, 0
PTMEAS/CART, (GAGEWIDTH+ENDCLEAR), 0, -(GWIDTH/2), 0, 1, 0
ENDMES
GOTO/0, SECU, -(GWIDTH/2)
MEAS/POINT,F(XORIG), 1
PTMEAS/CART, 0, -(GHEIGHT/6), -(GWIDTH/2), -1, 0, 0
ENDMES
D(@CRDLABEL) = DATSET/FA(ZPLANE), ZDIR, ZORIG, FA(XLINE), XDIR, YORIG, FA(XORIG), XORIG
D(@CRDLABEL) = TRANS/ZORIG, -PRBR, YORIG, -PRBR, XORIG, PRBR
ENDMAC
M(GAGECHECK) = MACRO/GHEIGHT, GWIDTH, GLENGTH, PRBR
DECL/LOCAL, REAL, XS, XE, ACTLENGTH
DECL/LOCAL, CHAR, 256, SSEP, STESTDATE, STESTTIME
DECL/LOCAL, INTGR, LPCOUNT
SSEP = ASSIGN/'--------------------------------------------------------------------------------'
WRITE/DID(GageBlock), SSEP
WRITE/DID(DEFAULTSCREEN),SSEP
F(PTS)=FEAT/POINT,CART,0 ,0, 0, -1, 0, 0
F(PTE)=FEAT/POINT,CART,GLENGTH ,0, 0, 1, 0, 0
DO/LPCOUNT, 1, STEP_NUM
GLENGTH = ASSIGN/GLENGTH+Gage_len
GOTO/0, SECU, -(GWIDTH/2)
MEAS/POINT,F(PTS), 1
PTMEAS/CART, 0, -(GHEIGHT/6), -(GWIDTH/2), -1, 0, 0
ENDMES
GOTO/0, SECU, -(GWIDTH/2)
GOTO/GLENGTH, SECU, -(GWIDTH/2)
MEAS/POINT,F(PTE), 1
PTMEAS/CART, GLENGTH, -(GHEIGHT/6), -(GWIDTH/2), 1, 0, 0
ENDMES
STESTDATE = ASSIGN/SDATE()
STESTTIME = ASSIGN/STIME()
WRITE/DID(GageBlock), 'DATE : ', STESTDATE, ' TIME : ', STESTTIME
WRITE/DID(DEFAULTSCREEN),'DATE : ', STESTDATE, ' TIME : ', STESTTIME
XS = OBTAIN/FA(PTS), 3
XE = OBTAIN/FA(PTE), 3
ACTLENGTH = ASSIGN/(XE - XS) - (2.0 * PRBR)
WRITE/DID(GageBlock), 'RUN ', LPCOUNT, 'Actual Length = ', ACTLENGTH, ' Nominal Length : ', GLENGTH
WRITE/DID(DEFAULTSCREEN),'RUN ', LPCOUNT, 'Actual Length = ', ACTLENGTH, ' Nominal Length : ', GLENGTH
GOTO/GLENGTH, SECU, -(GWIDTH/2)
GOTO/0, SECU, -(GWIDTH/2)
ENDDO
ENDMAC
DECL/COMMON,DOUBLE,DR_PRBRAD
DECL/COMMON, DOUBLE, VI, VJ, VK, VI2, VJ2, VK2
DECL/COMMON, DOUBLE, GAGEHEIGHT, GAGEWIDTH, ENDCLEAR
DECL/COMMON, DOUBLE, ZGAP[5], XGAP[5], BLENGTH[5], ZP, XP, BL
GAGEHEIGHT = ASSIGN/37
GAGEWIDTH = ASSIGN/10
ENDCLEAR = ASSIGN/5
XGAP[1] = ASSIGN/0
ZGAP[1] = ASSIGN/0
BLENGTH[1] = ASSIGN/Gage_Len
RECALL/D(MCS)
UNITS/MM,ANGDEC
PRCOMP/OFF
MODE/MAN
F(PTL1)=FEAT/POINT,CART,1 ,0, 0, 0, 0, 1
F(PTL2)=FEAT/POINT,CART,2 ,0, 0, 0, 0, 1
F(PTL3)=FEAT/POINT,CART,3 ,0, 0, 0, 0, 1
F(PTL4)=FEAT/POINT,CART,4 ,0, 0, 0, 0, 1
F(PTL5)=FEAT/POINT,CART,5 ,0, 0, 0, 0, 1
F(PTL6)=FEAT/POINT,CART,6 ,0, 0, 0, 0, 1
var_temp=PROMPT/TEXT,'点击继续在块规侧面取三个点建立平面'
MEAS/POINT,F(PTL1),1
ENDMES
MEAS/POINT,F(PTL2),1
ENDMES
MEAS/POINT,F(PTL3),1
ENDMES
var_temp=PROMPT/TEXT,'点击继续在块规端面取一点'
MEAS/POINT,F(PTL4),1
ENDMES
var_temp=PROMPT/TEXT,'点击继续在块规上表面取两个点建立轴线方向，注意取点顺序'
MEAS/POINT,F(PTL5),1
ENDMES
MEAS/POINT,F(PTL6),1
ENDMES
VI = OBTAIN/FA(PTL1)[1],5
VJ = OBTAIN/FA(PTL1)[1],6
VK = OBTAIN/FA(PTL1)[1],7
F(BFPL1) = FEAT/PLANE,CART, 0.0, 0.0, 0.0, VI, VJ, VK
VI = OBTAIN/FA(PTL5)[1],5
VJ = OBTAIN/FA(PTL5)[1],6
VK = OBTAIN/FA(PTL5)[1],7
VI2 = OBTAIN/FA(PTL4)[1],5
VJ2 = OBTAIN/FA(PTL4)[1],6
VK2 = OBTAIN/FA(PTL4)[1],7
F(BFLN1) = FEAT/LINE,BND,CART, 0, 0, 0, -VI2, -VJ2, -VK2, VI, VJ, VK
CONST/PLANE,F(BFPL1),BF,FA(PTL1),FA(PTL2),FA(PTL3)
CONST/LINE,F(BFLN1),BF,FA(PTL5),FA(PTL6)
D(GAGG1CRD) = DATSET/FA(BFPL1), ZDIR, ZORIG, FA(BFLN1), XDIR, YORIG, FA(PTL4), XORIG
DR_PRBRAD = ASSIGN/(Probe_D/2)
D(GAGG1CRD) = TRANS/ZORIG, -DR_PRBRAD, YORIG, -DR_PRBRAD, XORIG, DR_PRBRAD
DID(GageBlock) = DEVICE/STOR,'GagaBlockResult.out'
OPEN/DID(GageBlock), DIRECT, OUTPUT, APPEND
MODE/PROG,MAN
ZP = ASSIGN/ZGAP[1]
XP = ASSIGN/XGAP[1]
BL = ASSIGN/BLENGTH[1]
CALL/M(GAGECRDSETUP), (GAGE1CRD), XP, ZP, GAGEHEIGHT, GAGEWIDTH, BL, ENDCLEAR, DR_PRBRAD
CALL/M(GAGECHECK), GAGEHEIGHT, GAGEWIDTH, BL, DR_PRBRAD
CLOSE/DID(GageBlock)
