GATK官方推荐的workflow语言-WDL-CFANZ编程社区

欢迎关注"生信修炼手册"！

在GATK4的best practice中，不再像以前那样给出每个步骤对应的代码，而是直接给出了官方使用的pipeline。这些pipeline采用WDL进行编写。

WDL是一种流程编写语言，没有太多复杂的逻辑和语法，入门简单。首先看一个hello world的例子

workflow myWorkflow {
    call myTask
}
task myTask {
    command {
        echo "hello world"
    }
    output {
        String out = read_string(stdout())
    }
}

对于一个WDL脚本而言，有以下5个核心结构

workflow
task
call
command
output

每个脚本包含1个workflow， workflow由多个task构成。在workflow中，通过call调用对应的task。每个task在workflow代码块之外单独定义。

task代表任务，读取输入文件，执行相应命令，然后输出。command中对应的就是执行的命令，比如一条具体的gatk的命令，output 指定task的输出值。可以将task理解为编程语言中的函数，每个函数读取输入的参数，执行代码，然后返回，command对应执行的具体代码，output对应返回值。

在WDL中，也是可以传递参数的。task和workflow中的写法不同

1. task 中的参数

下面的示意图中，task 有3个输入的参数，文件类型的ref，in 和字符串类型的id。在command中，通过${ref}这种格式访问变量的值

GATK官方推荐的workflow语言-WDL_json

2. workflow 中的参数

下面的示意图中， workflow 有3个参数，文件类型的my_ref，my_input 和字符串类型的name。传递这3个参数给task时，直接传变量名就可以了。

GATK官方推荐的workflow语言-WDL_json_02

作为流程管理语言，需要对多个task统一管理。task之间具有多种关系

1. 一对一的依赖关系

前一个task的输出，作为后一个task的输入

GATK官方推荐的workflow语言-WDL_jar_03
示例如下

workflow LinearChain {
  File firstInput
  call stepA { input: in=firstInput }
  call stepB { input: in=stepA.out }
  call stepC { input: in=stepB.out }
}
task stepA {
  File in
  command { programA I=${in} O=outputA.ext }
  output { File out = "outputA.ext" }
}
task stepB {
  File in
  command { programB I=${in} O=outputB.ext }
  output { File out = "outputB.ext" }
}
task stepC {
  File in
  command { programC I=${in} O=outputC.ext }
  output { File out = "outputC.ext" }
}

一个task的多个输出作为下一个task的输入

GATK官方推荐的workflow语言-WDL_jar_04
示例如下：

workflow MultiOutMultiIn {
  File firstInput
  call stepA { input: in=firstInput }
  call stepB { input: in=stepA.out }
  call stepC { input: in1=stepB.out1, in2=stepB.out2 }
}
task stepA {
  File in
  command { programA I=${in} O=outputA.ext }
  output { File out = "outputA.ext" }
}
task stepB {
  File in
  command { programB I=${in} O1=outputB1.ext O2=outputB2.ext }
  output {
    File out1 = "outputB1.ext"
    File out2 = "outputB2.ext" }
}
task stepC {
  File in1
  File in2
  command { programB I1=${in1} I2=${in2} O=outputC.ext }
  output { File out = "outputC.ext" }
}

2. 多对多的依赖关系

一个task的输出作为多个task的输入，或者多个task的输出作为1个task的输入

GATK官方推荐的workflow语言-WDL_json_05

示例如下：

workflow BranchAndMerge {
  File firstInput
  call stepA { input: in=firstInput }
  call stepB { input: in=stepA.out }
  call stepC { input: in=stepA.out }
  call stepD { input: in1=stepC.out, in2=stepB.out }
}
task stepA {
  File in
  command { programA I=${in} O=outputA.ext }
  output { File out = "outputA.ext" }
}
task stepB {
  File in
  command { programB I=${in} O=outputB.ext }
  output { File out = "outputB.ext" }
}
task stepC {
  File in
  command { programC I=${in} O=outputC.ext }
  output { File out = "outputC.ext" }
}
task stepD {
  File in1
  File in2
  command { programD I1=${in1} I2=${in2} O=outputD.ext }
  output { File out = "outputD.ext" }
}

3. 平行关系

多个task之间完全平行，可以并行执行

GATK官方推荐的workflow语言-WDL_json_06

示例如下：

workflow ScatterGather {
  Array[File] inputFiles
  scatter (oneFile in inputFiles) {
    call stepA { input: in=oneFile }
  }
  call stepB { input: files=stepA.out }
}
task stepA {
  File in
  command { programA I=${in} O=outputA.ext }
  output { File out = "outputA.ext" }
}
task stepB {
  Array[File] files
  command { programB I=${files} O=outputB.ext }
  output { File out = "outputB.ext" }
}

task和函数还是有一定的区别，函数可以在代码中多次调用，但是task多次调用会有风险。下面的示意图中，stepA 运行两次，一次作为stepB的输入，一次作为stepC的输入。如果stepA的两次调用并行执行，当执行完之后，在传递给下一个task时，由于存在两个同名的stepA, stepB和stepC 就会无法正确接受参数。

GATK官方推荐的workflow语言-WDL_wdl_07

WDL中提供了解决方案，叫做task alias, 为task起一个别名，示例如下

workflow taskAlias {
  File firstInput
  File secondInput
  call stepA as firstSample { input: in=firstInput }
  call stepA as secondSample { input: in=secondInput }
  call stepB { input: in=firstSample.out }
  call stepC { input: in=secondSample.out }
}
task stepA {
  File in
  command { programA I=${in} O=outputA.ext }
  output { File out = "outputA.ext" }
}
task stepB {
  File in
  command { programB I=${in} O=outputB.ext }
  output { File out = "outputB.ext" }
}
task stepC {
  File in
  command { programC I=${in} O=outputC.ext }
  output { File out = "outputC.ext" }
}